7. További fontos utasítások és függvények. Unitok

Mûveletek, függvények és utasítások:

• a MOD b a-nak b-vel vett osztási maradéka (a és b egész típusú)
• a DIV b a-ban hányszor van meg a b (maradékos osztással)
• RANDOMIZE megkeveri a véletlenszám-generátort
• RANDOM(n) függvény, véletlen egész szám 0 és n-1 között (n egész típusú)
• RANDOM függvény, véletlen törtszám 0 és 1 között
• SQR(r) függvény, r négyzete
• SQRT(r) függvény, r négyzetgyöke
• ABS(r) függvény, r abszolútértéke
• SIN(r), COS(r) ARCTAN(r) trigonometriai függvények. Radiánban számolnak
• CHR(n) függvény, n ASCII-kódú karakter

Az eredeti Pascal nyelvet nagyon sok utasítással egészítették ki. Ezek az utasítások (pontosabban eljárások, függvények, konstansok és típusok, ld. késõbb) úgynevezett unitokban (más szóval, modulokban) foglalnak helyet. Ha használni akarjuk õket, el kell helyeznünk a deklarációs részben a

• USES unitlista;

deklarációs utasítást (ez a PROGRAM deklaráció kivételével meg kell, hogy elõzze az összes többi deklarációt!). Ekkor a fordító felismeri a megadott unit utasításait. A legfontosabb unitok a CRT (szöveges képernyõkezelés, billentyûzetkezelés, hangok), GRAPH (grafika), DOS (Dos-feladatok elvégzése: lemez-, file-, idõ- és megsza kításkezelés). A Pascal leggyakoribb utasításai a SYSTEM unitban vannak, de ezt a unitot nem kell deklarálni. Más unitok vagy a TURBO.TPL file-ban, vagy a megfelelõ nevû .TPU kiterjesztésû file-ban vannak.

A CRT unit fõbb lehetõségei:

• READKEY függvény, leütött billentyû (CHAR típusú). Ha nincs leütött billentyû, várakozik
• KEYPRESSED függvény, van-e leütött billentyû (logikai)
• SOUND(n) n Hz-es hangot kapcsol be
• NOSOUND kikapcsolja a szóló hangot
• DELAY(n) n ezredmásodpercig várakozik
• TEXTCOLOR(szín) a szöveg színe
• TEXTBACKGROUND(szín) a szöveg háttérszíne
• GOTOXY(x,y) a megadott koordinátájú helyre állítja a kurzort
• WHEREX függvény, a kurzor x-koordinátája
• WHEREY függvény, a kurzor y-koordinátája
• CLRSCR képernyõtörlés

A képernyõkezeléshez tudnunk kell, hogy a szöveges képernyõ bal felsõ sarkának x- és y-koordinátája (1,1), a jobb alsó saroké pedig (80,25). Ha a jobb alsó sarokba írunk egy karaktert, a program az egész képernyõt egy sorral feljebb lépteti.

Következzék a klasszikus pattogtató program, mely egy karaktert pattogtat a képernyõn egy téglalap alakú tartományban.

USES Crt;
VAR x,y:integer; {a pont helye}
    vx,vy:integer; {a pont függõleges és vízszintes sebessége}
    i:integer;
    c:char;
BEGIN
 Randomize;
 vx:=1;
 vy:=1; {a pont jobbra lefelé indul}
 x:=random(8)+3; {egy 2 és 10 közötti véletlenszám lesz}
 y:=random(8)+3; {a pont kiinduló helye}
 Clrscr;
 For i:=1 to 12 do Begin {keret rajzolása}
    Gotoxy(i,1); Write('-');
    Gotoxy(i,12); Write('-');
    Gotoxy(1,i); Write('|');
    Gotoxy(12,i); Write('|');
 End;
 c:='*'; {azért, hogy kezdetben biztosan ne legyen szóköz}
 Repeat
    Gotoxy(x,y); Write('O'); {kirajzoljuk a pontot}
    Delay(50);
    Gotoxy(x,y); Write(' '); {eltüntetjük}
    If (x=11) or (x=2) Then Begin {ha a falhoz ért}
       vx:=-vx; {visszafordul}
       Sound(500); delay(10); nosound; {hangkiadás}
    End;
    If (y=11) or (y=2) Then Begin
       vy:=-vy;
       Sound(500); delay(10); nosound;
    End;
    x:=x+vx; y:=y+vy; {a pont új helye}
    If Keypressed Then c:=readkey; {lenyomott billentyû beolvasása}
 Until c=(' '); {szóközre leáll a program}
END.

Nagyfelbontású grafika: a GRAPH unit

Igényesebb grafika esetén a nagyfelbontású lehetõségeket kell felhasználnunk a GRAPH unitból. A Pascal a video- kártya több üzemmódját is képes kezelni. A video-kártyától függõen a program más-más grafikus drivert használ (ezek olyan gépi kódú programgyûjtemények, melyeket a fordító nem fordít bele a tárgykódba, hanem csak a grafika bekapcsolásakor kerülnek a memóriába). A driverek .BGI kiterjesztésû file-okban helyezkednek el a lemezen. Egy adott driver esetén is több üzemmód közül választhatunk. Az üzemmódot jellemzi, hogy hány képpontot tud megjeleníteni vízszintesen és függõlegesen, és hány színben. A képernyõ bal felsõ sarkának grafikus koordinátái (0,0), így pl. a 640´480-as felbontásnál a jobb alsó sarok koordinátái (639,479). A .BGI file-okhoz hasonlóan mûködnek a .CHR file-ok, melyek betûtípusokat tartalmaznak, és csak a megfelelõ betûtípus beállításakor kerülnek be a memóriába.

A GRAPH unit fõbb utasításai:

• INITGRAPH(a,b,útvonal) a driver és az üzemmód száma alapján a grafika bekapcsolása. Ez az utasítás tölti be a megfelelõ drivert is. a és b a megfelelõ számokat tartalmazó változók kell, hogy legyenek, mert bennük a program hiba esetén „visszaüzen". Az útvonal a .BGI és .CHR file-okat tartalmazó könyvtár elérési útvonala. Az utasítás letörli a grafikus képernyõt
• PUTPIXEL(x,y,szín) pont kirajzolása
• GETPIXEL(x,y) függvény, az (x,y) koordinátájú pont színe
• SETCOLOR(szín) rajzolandó vonalak és körvonalak színének beállítása
• SETFILLSTYLE(minta,szín) kitöltés mintájának és színének beállítása.
• CIRCLE(x,y,sugár) megadott középponttal és sugárral kört rajzol
• LINE(x1,y1,x2,y2) (x1,y1) kezdõponttal és (x2,y2) végponttal szakaszt rajzol
• RECTANGLE(x1,y1,x2,y2) téglalapot rajzol, szemben lévõ sarkainak koordinátái (x1,y1) és (x2,y2)
• BAR(x1,y1,x2,y2) kitöltött téglalapot rajzol
• CLEARDEVICE letörli a képernyõt
• CLOSEGRAPH visszakapcsol szöveges üzemmódba (a grafika elvész)
• OUTTEXTXY(x,y,s) s stringet kiírja (x,y) koordinátájú ponttól
• SETTEXTSTYLE(font,irány,méret) bekapcsolja a megadott sorszámú betûtípust, a megadott betûméretet, és a vízszintes vagy függõleges szövegirányt

A további lehetõségeket lásd a help-ben.